modules/office/calcurse/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Text-based calendar and scheduling application
{
  config,
  lib,
  pkgs,
  ...
}:
let
  calcursePackage =
    if config.development.nixvim.enable then
      pkgs.symlinkJoin {
        name = "calcurse-wrapped";
        paths = [ pkgs.calcurse ];
        nativeBuildInputs = [ pkgs.makeWrapper ];
        postBuild = ''
          wrapProgram $out/bin/calcurse --set PAGER "nvim"
        '';
        meta = pkgs.calcurse.meta // {
          mainProgram = "calcurse";
        };
      }
    else
      pkgs.calcurse;
in
{
  options.office.calcurse = {
    enable = lib.mkEnableOption "Enables calcurse.";
    package = lib.mkOption {
      type = lib.types.package;
      readOnly = true;
      default = calcursePackage;
      description = "The calcurse package to use.";
    };
  };
  config = lib.mkIf config.office.calcurse.enable {
    home.packages = [ config.office.calcurse.package ];
    xdg.configFile."calcurse/conf" = {
      source = ./conf;
      force = true;
    };
    xdg.configFile."calcurse/keys" = {
      source = ./keys;
      force = true;
    };
  };
}