blob: 980718d502cc83be233b6a7263b5441ee797e709 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
# Home Manager configuration for Arpit's NixOS system.
# The module set is also exposed as `homeManagerModules.default` so other
# configurations can import this repo as a flake input.
{
description = "Home Manager configuration of arpit, exposing a reusable homeManagerModules.default.";
inputs = {
# Use nixpkgs from the local registry to save disk space on duplicate derivations
nixpkgs.url = "nixpkgs";
home-manager = {
url = "github:nix-community/home-manager/master";
inputs.nixpkgs.follows = "nixpkgs";
};
base16.url = "github:SenchoPens/base16.nix";
nixvim.url = "github:nix-community/nixvim";
devenv = {
url = "github:cachix/devenv";
inputs.nixpkgs.follows = "nixpkgs";
};
};
nixConfig = {
extra-substituters = [
"https://cache.nixos.org"
"https://nix-community.cachix.org"
"https://devenv.cachix.org"
];
extra-trusted-public-keys = [
"cache.nixos.org-1:6NCHdD59X431o0gWypbMrAURkbJ16ZPMQFGspcDShjY="
"nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs="
"devenv.cachix.org-1:w1cLUi8dv3hnoSPGAuibQv+f9TZLr6cv/Hm9XgU50cw="
];
};
outputs =
{
self,
nixpkgs,
home-manager,
base16,
nixvim,
devenv,
...
}@inputs:
let
system = "x86_64-linux";
pkgs = nixpkgs.legacyPackages.${system};
updates = import ./updates {
inherit pkgs;
lib = pkgs.lib;
};
# The module set, bundled with the prerequisites it relies on: the
# base16 module (provides `config.scheme`) and the nixvim module
# (provides `programs.nixvim`). A default `scheme` is set so it works
# out of the box; consumers can override it with their own path.
homeManagerModule =
{
lib,
...
}:
{
imports = [
base16.homeManagerModule
nixvim.homeModules.nixvim
./modules
];
scheme = lib.mkDefault ./assets/onedark-dark.yml;
};
in
{
homeManagerModules = {
default = homeManagerModule;
};
apps.${system}.updates = {
type = "app";
program = "${updates}/bin/updates";
};
formatter.${system} = pkgs.nixfmt-tree;
devShells.${system}.default = devenv.lib.mkShell {
inherit inputs pkgs;
modules = [
(
{ ... }:
{
git-hooks.hooks.nixfmt.enable = true;
git-hooks.hooks.forbid-private = {
enable = true;
name = "Forbid committing private files";
entry = "found private file in staging! Do not commit users/arpit/private.nix.";
language = "fail";
files = "users/arpit/private\\.nix$";
};
languages = {
lua = {
enable = true;
lsp = {
enable = true;
package = pkgs.lua-language-server;
};
};
nix = {
enable = true;
lsp = {
enable = true;
package = pkgs.nixd;
};
};
shell = {
enable = true;
lsp = {
enable = true;
package = pkgs.bash-language-server;
};
};
};
}
)
];
};
homeConfigurations = {
arpit =
let
system = "x86_64-linux";
pkgs = import nixpkgs {
inherit system;
};
in
home-manager.lib.homeManagerConfiguration {
inherit pkgs;
modules = [
./users/arpit
self.homeManagerModules.default
];
};
};
};
}
|
